/**************************************************************/
/*  File evmlink.cmd                                          */
/*    This linker command file can be used as the starting    */
/*  point for linking programs for the TMS320C6701 EVM.  It   */
/*  assumes that memory MAP 1 has been selected.  Almost all  */
/*  sections have been allocated to internal memory. If       */
/*  more memory is needed sections can be mapped to external  */
/*  memory.                                                   */
/*     The external SBSRAM has been divided into program      */
/* (SBSRAM_PROG_MEM) and data (SBSRAM_DATA_MEM) memory. The   */
/* lengths of each type of memory can be changed as desired.  */
/**************************************************************/

-c
-heap  0x400
-stack 0x400

MEMORY
{
  /* Internal program memory, 16K 32-bit instructions  */
  INT_PROG_MEM (RX)    : origin = 0x00000000 length = 0x00010000

  /* Internal data memory, 64K bytes */
  INT_DATA_MEM (RW)    : origin = 0x80000000 length = 0x00010000

  /* External synchronous burst static RAM. 256K bytes  */
  SBSRAM_PROG_MEM (RX) : origin = 0x00400000 length = 0x00020000
  SBSRAM_DATA_MEM (RW) : origin = 0x00420000 length = 0x00020000

  /* External synchronous dynamic RAM, 8M bytes  */
  SDRAM0_DATA_MEM (RW) : origin = 0x02000000 length = 0x00400000
  SDRAM1_DATA_MEM (RW) : origin = 0x03000000 length = 0x00400000
}

SECTIONS
{
  .vec:     load = 0x00000000 /* Interrupt vectors included */
                              /*by using dev6x.lib  */ 
/* Use SBSRAM_PROG_MEM for .text if it cannot fit in INT_PROG_MEM */
/*  .text:    load = SBSRAM_PROG_MEM */ /* Executable code */

  .text:    load = INT_PROG_MEM /* Executable code */ 
  .const:   load = INT_DATA_MEM /* Initialized constants */
  .bss:     load = INT_DATA_MEM /* Global and static variables */
  .data:    load = INT_DATA_MEM /* Data from .asm programs */
  .cinit:   load = INT_DATA_MEM /* Tables for initializing */
                                /* variables and constants */
  .stack:   load = INT_DATA_MEM /* Stack for local variables */
  .far:     load = INT_DATA_MEM /* Global and static variables */
                                /* declared far */
  .sysmem:  load = SDRAM0_DATA_MEM /* Used by malloc, etc. */
  .cio:     load = INT_DATA_MEM /* Used for C I/O functions */
  .ipmtext: load = INT_PROG_MEM /* Used by dev6x.lib */
}