#!/bin/csh
#
# @(#).cshrc	1.28	02/06/99

# My settings for environment variables and aliases
source $HOME/.mycshrc

# Path setting independent of specific tools and operating systems
set basicpath = (/usr/ucb /usr/sbin /usr/bin /bin)
set iopath = (/usr/dt/bin)
set localpath = (/usr/local/packages/mathematica3.0/Executables/Solaris \
 /usr/local/bin $JAVA/bin /usr/local/gnu/bin \
 /usr/local/packages/kerberos/bin $FMHOME/bin $NISTHOME/pcasys/bin)

set xwindowspath = ()
foreach xdir (/usr/local/X11/bin /usr/X11/bin /usr/bin/X11 $OPENWINHOME/bin)
  if (-d $xdir) then
    set xwindowspath = $xdir
    break
  endif
end

set path = ($localpath $basicpath $iopath $xwindowspath)

# Add to the path based on the operating system being used
set sunpath = (/opt/SUNWspro/bin)
set sun4path = (/usr/local/hosts)
set solarispath = (/usr/ccs/bin /usr/5bin /opt/hpnp/bin /opt/bin)
set hppath = (/opt/langtools/bin)

if ( $PTARCH =~ sol2* ) then
  set path = ($path $sunpath $solarispath)
else if ($PTARCH == sun4 ) then
  set path = ($path $sunpath $sun4path)
else if ( $PTARCH =~ hppa* ) then
  set path = ($path $hppath)
endif

# Add to the shared library path according to the local LRC setup
# SHLIB_PATH is for HPs; LD_LIBRARY_PATH is for other Unix operating systems
if ( $PTARCH =~ hppa* ) then
  set hpxwinlibs=/usr/local/X11/lib
  set hpuserlibs=/usr/lib
  setenv SHLIB_PATH {$hpxwinlibs}:{$hpuserlibs}:{$SHLIB_PATH}
else
  set solxwinlibs={$OPENWINHOME}/lib:/usr/local/X11/lib
  set soluserlibs=/usr/lib:/usr/ucblib:/usr/dt/lib
  setenv LD_LIBRARY_PATH {$solxwinlibs}:{$soluserlibs}:${LD_LIBRARY_PATH}
endif

# Java additions
# if ( $PTARCH =~ sol2* ) then
#   setenv LD_LIBRARY_PATH {$JAVA_LIB}:{$LD_LIBRARY_PATH}
# endif
# setenv CLASSPATH .:{$JAVA}/lib/classes.zip

# Ptolemy developer installation
if ($?PTOLEMY) then
  set path=($PTOLEMY/vendors/bin $path $PTOLEMY/doc/bin)
  # S-56X DSP card
  setenv S56DSP $PTOLEMY/vendors/s56dsp
  if ( $PTARCH =~ sol* ) then
    setenv LD_LIBRARY_PATH {$LD_LIBRARY_PATH}:{$S56DSP}/lib
  endif
endif

# Ptolemy user installation
if ($?PTOLEMY) then
  # Note that $PTOLEMY/bin has to go before $PTOLEMY/bin.$PTARCH for
  # tycho and mkPtolemyTree to work
  set path=($PTOLEMY/bin $PTOLEMY/bin.$PTARCH $path)
endif

if ($?A_DIR) then
  set path=($A_DIR $path)
endif

# My own shell scripts and Unix utilities
set path=($HOME/bin/$PTARCH $HOME/bin/scripts $path)

# Open Windows causes Mathematica kernel to mess up display of graphics
# unsetenv OPENWINHOME
# set path = `echo $path | sed -e 's+/usr/openwin/bin ++'`

# HPs and AIX machines do not recognize the limit command
if ( $PTARCH =~ sol2* ) then
	#  Allow 128 files to be open at the same time for Purify
	limit descriptors 128

	# Do not allow core dumps to be created
	limit coredumpsize 0
endif

# The $?prompt is true if this is being executed by a terminal
if ($?prompt) then
	source $HOME/.mylogin
endif

# Synopsys tools
if (($?SYNOPSYS) && (-f $SYNOPSYS/admin/install/sim/bin/environ.csh)) then
  source $SYNOPSYS/admin/install/sim/bin/environ.csh
endif